***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 31, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4SMAJ5P0CA 1 2 
.param
+vc0 = -2.002e-5	vc1 = 2.416e-7		vc2 = 2.043e-5		vc3 = 7.225e-1
+tc1 = 4.511e-4		tc2 = 1.601e-3		tc3 = 3.011e-3		tc4 = 2.371e-3
d1 1 c zener
g1 c 1 value = {(vc0+vc1*v(c,1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,1))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d2 2 c zener
g2 c 2 value = {(vc0+vc1*v(c,2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,2))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1   
***** dc model parameter *****
+ is = 1e-13		   n = 1		  rs = 1e-3
+ibv = 10e-3		 nbv = 1.5		  bv = 6
***** capacitance parameter *****
+cjo = 1.633e-9		   m = 2.123e-1		  vj = 2.293
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.221		 xti = 3
+trs1 = 1e-4		tbv1 = 4.355e-4		tbv2 = 3.538e-8
.ends P4SMAJ5P0CA
*$
